ANSYS中关于初应力和荷载步设置的算例
[转载]ANSYS中关于初应力和荷载步设置的算例(2011-02-20 16:30:41)转载▼标签： 转载
原文地址：ANSYS中关于初应力和荷载步设置的算例作者：WaterSprite
偶初学ANSYS，看了网站上几个朋友关于应力和加载方式的讨论，自己做了一个小算例，现在发上来和大家共同讨论一下这方面的问题。
算例为一个地基+地基上面的一块方块墙吧，先通过一次计算仅加边界条件和自重，计算得到自重应力场，并输出初应力文件用来模拟初应力场。
然后施加应力和自重并进行计算，此时的位移基本为0，即消除了初位移，所得应力场即为自重应力场。在些基础上进一步施加墙上法向面荷载，并进行第二步计算，得到的位移应该是仅有面荷载引起的位移。
关于初应力想说明的几点：
1、初应力只能加在第一个荷载步，用命令流和GUI方式均可。但在求解前不能退出求解器，如果加了初应力后退出求解器到前处理器或者后处理器后再回到前处理器，刚才施加的初应力就没有了，必须再次施加。
2、也可以不用初应力而直接分两个荷载步进行计算，如第一步仅计算自重，第二步再加面荷载后进行计算，在后处理中用工况组合来得到“净位移”，但工况组合中的应力结果似乎是不正确的。
3、如果用LSSOLVE从荷载文件进行求解，在写荷载文件时初应力的设置并不会写入荷载文件，所以，在命令流或者GUI方式下在求解前必须显示指定加载初应力。
关于荷载步设置的几点建议：
1、在GUI方式下，每次进入求解器进行求解似乎都是开始一个新的分析（这一点偶也不是很明白）。如果不退出求解器，即便不改变约束和荷载，只要求解一次，就会多一个荷载步结果，但所有结果是一样的；如果退出求解器后再进来，求解就重新开始（根据时间值）。
2、对点、线、面、体荷载都有替换和叠加两种方式，在替换方式下，在同一位置重复加荷载，只有最后一次加的荷载有效；在叠加方式下，在同一位置重复加荷载，所有荷载会叠加后共同作用在结构上。
以上是偶刚学ANSYS的一点小小总结，不正之处还望大家指正，也欢迎大家与偶一块讨论，偶QQ：1694440
/BATCH
KEYW,PR_SET,1
KEYW,PR_STRUC,1
KEYW,PR_THERM,0
KEYW,PR_FLUID,0
KEYW,PR_ELMAG,0
KEYW,MAGNOD,0
KEYW,MAGEDG,0
KEYW,MAGHFE,0
KEYW,MAGELC,0
KEYW,PR_MULTI,0
KEYW,PR_CFD,0
/GO
!*
/prep7
!* define material proterties
mp,dens,1,2490
mp,ex,1,20e9
mp,prxy,1,.167
mp,dens,2,2660
mp,ex,2,10e9
mp,prxy,2,.28
!* define element type
et,1,solid45
!* define geometry
block,-5,-0.5,-5,5,-5,0
block,-0.5,0.5,-5,5,-5,0
block,0.5,5,-5,5,-5,0
block,-0.5,0.5,-5,5,0,5
vglue,all
vsel,s,loc,z,-6,0
vatt,1,,1,0
vsel,
inve
vatt,2,,1,0
!* mesh geometry
ESIZE,0,10
lsel,s,loc,x,-0.4,0.4
lesize,all,,,4
allsel,all
vmesh,all
ASEL,S,LOC,Z,-6,-0.1
ASEL,U,LOC,X,-0.6,-0.4
ASEL,U,LOC,X,0.4,0.6
cm,uxyz,area
asel,s,loc,z,0,5
asel,r,loc,x,0.4,0.6
cm,sfload,area
ALLSEL,ALL
FINISH
/SOLU
!*
ANTYPE,0
!* the zero load step only for get initial stress file
lsclear,all
TIME,1
AUTOTS,-1
NSUBST,1, , ,1
KBC,0
!* define constrains
cmsel,s,uxyz
da,all,all,0.
!* deifine gravity
acel,0.,0.,10.
allsel,all
iswrite,on !* open option for write initial stress file
solve
FINISH
/SOLU
!*
ANTYPE,0
!* the first load step
lsclear,all
TIME,1
AUTOTS,-1
NSUBST,1, , ,1
KBC,0
!* define constrains
cmsel,s,uxyz
da,all,all,0.
!* deifine gravity
acel,0.,0.,10.
allsel,all
ISFILE,READ,AINIStress,ist, ,1 !*初应力仅在第一个荷载步施加
iswrite,off
solve
!* the second load step
lsclear,all
TIME,2
AUTOTS,-1
NSUBST,1, , ,1
KBC,0
!* define constrains
cmsel,s,uxyz
da,all,all,0.
!* deifine gravity
acel,0.,0.,10.
!* define surface load
cmsel,s,sfload
sfa,all,1,pres,10000
allsel,all
iswrite,off
solve
/prep7
set,first
plnsol,u,z,0,1.0 !* 查看初位移应该基本为0
plnsol,s,z,0,1.0 !* 可以查到初应力是存在的
set,last
plnsol,u,z,0,1.0 !* 查看仅面荷载引起的位移
plnsol,s,z,0,1.0 !* 查看应力结果