移动载荷作用下桥梁的动态响应

/filname,mobileforce,1
keyw,pr_struc,1
/prep7
/config,nrst,2000 !定义最大的计算结果子步为2000步
!定义单元类型
et,1,beam3
!定义实常数
r,1,0.1,0.0001/12,0.1
!定义材料属性
mp,ex,1,207e9
mp,prxy,1,0.3
mp,dens,1,2000
!定义相关标量参数，路径parameter>scalar parameter
*SET,deltl,32/100
*SET,v,120
*SET,deltt,deltl/v*3.6
*SET,f,1000
*SET,w,10
!建立网格化模型,将整个简支梁划分为100个单元，则车子的前后轮之间将包含2.56/（32/100）=8个单元
n,1
n,101,32
fill,1,101
*do,i,1,100,1
e,i,i+1
*enddo
!加载与求解
!匀速常量力 的情况
!(1)指定分析类型
/solu
antype,4
trnopt,full
LUMPM,0

!(2)位移边界条件
d,1,all
d,101,all
!(3)施加常量力并求解
*do,ii,1,101+8,1
outres,all,all !输出所有加载子步的所有结果
time,ii*deltt !每个载荷步的最终求解时间
nsubst,5 !每个载荷步包含五个载荷子步
*if,ii,lt,8,then
fdele,all,all !删除所有集中力载荷
nsel,s,loc,x,(ii-1)*deltl !选择集中力作用节点
f,all,fy,-f !施加集中载荷
allsel
solve
*elseif,ii,lt,101
fdele,all,all
nsel,s,loc,x,(ii-1)*deltl
nsel,a,loc,x,(ii-7-1)*deltl
f,all,fy,-f
allsel
solve
*else
fdele,all,all
nsel,s,loc,x,(ii-7-1)*deltl
f,all,fy,-f
allsel
solve
*endif
*enddo





!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!匀速简谐力的情况
！简谐力的施加与常量力的施加过程差不多，只需将上面的第三步路径命令流改为如下形式
!注意：以下命令流不是续接第（3）步，而是代替第（3）步的命令流
*do,ii,1,101+8,1
outres,all,all !输出所有加载子步的所有结果
time,ii*deltt !每个载荷步的最终求解时间
nsubst,5 !每个载荷步包含五个载荷子步
*if,ii,lt,8,then
fdele,all,all !删除所有集中力载荷
nsel,s,loc,x,(ii-1)*deltl !选择集中力作用节点
f,all,fy,-f*cos(w*(ii-1)*deltt) !施加集中载荷
allsel
solve
*elseif,ii,lt,101
fdele,all,all
nsel,s,loc,x,(ii-1)*deltl
nsel,a,loc,x,(ii-7-1)*deltl
f,all,fy,-f*cos(w*(ii-1)*deltt)
allsel
solve
*else
fdele,all,all
nsel,s,loc,x,(ii-7-1)*deltl
f,all,fy,-f*cos(w*(ii-1)*deltt)
allsel
solve
*endif
*enddo